A1

부록 I

다음은 Lox를 위한 완전한 문법입니다. 언어의 각 부분을 소개하는 장에 문법 규칙이 포함되어 있지만, 여기서는 모든 규칙을 한곳에 모아두었습니다.

A1 . 1구문 문법

구문 문법은 선형적인 토큰 시퀀스를 중첩된 구문 트리 구조로 파싱하는 데 사용됩니다. 이 문법은 전체 Lox 프로그램(또는 단일 REPL 엔트리)과 일치하는 첫 번째 규칙으로 시작합니다.

program        → declaration* EOF ;

A1 . 1 . 1선언

프로그램은 일련의 선언으로 구성됩니다. 선언은 새로운 식별자를 바인딩하거나 다른 구문 유형 중 하나에 해당하는 문장입니다.

declaration    → classDecl
               | funDecl
               | varDecl
               | statement ;

classDecl      → "class" IDENTIFIER ( "<" IDENTIFIER )?
                 "{" function* "}" ;
funDecl        → "fun" function ;
varDecl        → "var" IDENTIFIER ( "=" expression )? ";" ;

A1 . 1 . 2구문

나머지 구문 규칙들은 부수 효과를 발생시키지만, 바인딩을 도입하지는 않습니다.

statement      → exprStmt
               | forStmt
               | ifStmt
               | printStmt
               | returnStmt
               | whileStmt
               | block ;

exprStmt       → expression ";" ;
forStmt        → "for" "(" ( varDecl | exprStmt | ";" )
                           expression? ";"
                           expression? ")" statement ;
ifStmt         → "if" "(" expression ")" statement
                 ( "else" statement )? ;
printStmt      → "print" expression ";" ;
returnStmt     → "return" expression? ";" ;
whileStmt      → "while" "(" expression ")" statement ;
block          → "{" declaration* "}" ;

block은 구문 규칙이지만, 함수 본문과 같은 다른 몇몇 규칙에서 비종단(nonterminal)으로도 사용된다는 점에 유의하십시오.

A1 . 1 . 3표현식

표현식은 값을 생성합니다. Lox는 다양한 우선순위를 가진 여러 단항 및 이항 연산자를 가지고 있습니다. 일부 언어의 문법은 우선순위 관계를 직접 인코딩하지 않고 다른 곳에서 명시하기도 합니다. 여기서는 각 우선순위 수준마다 별도의 규칙을 사용하여 이를 명시적으로 나타냅니다.

expression     → assignment ;

assignment     → ( call "." )? IDENTIFIER "=" assignment
               | logic_or ;

logic_or       → logic_and ( "or" logic_and )* ;
logic_and      → equality ( "and" equality )* ;
equality       → comparison ( ( "!=" | "==" ) comparison )* ;
comparison     → term ( ( ">" | ">=" | "<" | "<=" ) term )* ;
term           → factor ( ( "-" | "+" ) factor )* ;
factor         → unary ( ( "/" | "*" ) unary )* ;

unary          → ( "!" | "-" ) unary | call ;
call           → primary ( "(" arguments? ")" | "." IDENTIFIER )* ;
primary        → "true" | "false" | "nil" | "this"
               | NUMBER | STRING | IDENTIFIER | "(" expression ")"
               | "super" "." IDENTIFIER ;

A1 . 1 . 4보조 규칙

위 규칙들을 좀 더 깔끔하게 유지하기 위해 일부 문법은 몇 가지 재사용되는 보조 규칙으로 분리되었습니다.

function       → IDENTIFIER "(" parameters? ")" block ;
parameters     → IDENTIFIER ( "," IDENTIFIER )* ;
arguments      → expression ( "," expression )* ;

A1 . 2어휘 문법

어휘 문법은 스캐너가 문자를 토큰으로 그룹화하는 데 사용됩니다. 구문 문법이 문맥 자유 문법인 반면, 어휘 문법은 정규 문법입니다—재귀 규칙이 없다는 점에 유의하십시오.

NUMBER         → DIGIT+ ( "." DIGIT+ )? ;
STRING         → "\"" <어떤 문자도 가능, 단 큰따옴표(\") 제외>* "\"" ;
IDENTIFIER     → ALPHA ( ALPHA | DIGIT )* ;
ALPHA          → "a" ... "z" | "A" ... "Z" | "_" ;
DIGIT          → "0" ... "9" ;